home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / umich / falcon / programm.ing / nt_dsp1.lzh / NT_DSP1.MSA / FFT / FFTR2B.ASM < prev    next >
Assembly Source File  |  1990-01-17  |  4KB  |  117 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ; Radix 2, In-Place, Decimation-In-Time FFT (faster than fftr2a.asm)
  7. ; 
  8. ; Last Update 02 Oct 86   Version 1.1
  9. ;
  10. fftr2b  macro   points,data,coef
  11. fftr2b  ident   1,1
  12. ;
  13. ; Radix 2 Decimation in Time In-Place Fast Fourier Transform Routine
  14. ;
  15. ;    Complex input and output data
  16. ;        Real data in X memory
  17. ;        Imaginary data in Y memory
  18. ;    Normally ordered input data
  19. ;    Bit reversed output data
  20. ;       Coefficient lookup table
  21. ;        -Cosine values in X memory
  22. ;        -Sine values in Y memory
  23. ;
  24. ; Macro Call - fftr2b   points,data,coef
  25. ;
  26. ;       points     number of points (4-32768, power of 2)
  27. ;       data       start of data buffer
  28. ;       coef       start of sine/cosine table
  29. ;
  30. ; Alters Data ALU Registers
  31. ;       x1      x0      y1      y0
  32. ;       a2      a1      a0      a
  33. ;       b2      b1      b0      b
  34. ;
  35. ; Alters Address Registers
  36. ;       r0      n0      m0
  37. ;       r1      n1      m1
  38. ;               n2
  39. ;
  40. ;       r4      n4      m4
  41. ;       r5      n5      m5
  42. ;       r6      n6      m6
  43. ;
  44. ; Alters Program Control Registers
  45. ;       pc      sr
  46. ;
  47. ; Uses 6 locations on System Stack
  48. ;
  49. ; Latest Revision - September 30, 1986
  50. ;
  51.         move    #points/2,n0    ;initialize butterflies per group
  52.         move    #1,n2           ;initialize groups per pass
  53.         move    #points/4,n6    ;initialize coefficient offset
  54.         move    #-1,m0          ;initialize address modifiers
  55.         move    m0,m1           ;for linear addressing
  56.         move    m0,m4
  57.         move    m0,m5
  58.         move    #0,m6           ;initialize coefficient address modifier
  59.                                 ;for reverse carry (bit reversed) addressing
  60. ;
  61. ; Do all FFT passes but last pass
  62. ;
  63.         do      #@cvi(@log(points)/@log(2)-0.5),_end_pass
  64.         move    #data,r0                ;initialize A input pointer
  65.         move    r0,r4                   ;initialize A output pointer
  66.         lua     (r0)+n0,r1      ;initialize B input pointer
  67.         move    #coef,r6        ;initialize C input pointer
  68.         lua     (r1)-,r5        ;initialize B output pointer
  69.         move    n0,n1           ;initialize pointer offsets
  70.         move    n0,n4
  71.         move    n0,n5
  72.  
  73.         do      n2,_end_grp
  74.         move    x:(r1),x1       y:(r6),y0       ;lookup -sine value
  75.         move    x:(r5),a        y:(r0),b
  76.         move    x:(r6)+n6,x0            ;lookup -cosine value
  77.  
  78.  
  79.         do      n0,_end_bfy     ;Radix 3 DIT butterfly kernel with constant
  80.         mac     x1,y0,b                         y:(r1)+,y1  ;twiddle factor
  81.         macr    -x0,y1,b        a,x:(r5)+       y:(r0),a
  82.         subl    b,a             x:(r0),b        b,y:(r4)
  83.         mac     -x1,x0,b        x:(r0)+,a       a,y:(r5)
  84.         macr    -y1,y0,b        x:(r1),x1
  85.         subl    b,a             b,x:(r4)+       y:(r0),b
  86. _end_bfy
  87.         move    a,x:(r5)+n5     y:(r1)+n1,y1    ;dummy load of x1 and y1
  88.         move    x:(r0)+n0,x1    y:(r4)+n4,y1
  89. _end_grp
  90.         move    n0,b1
  91.         lsr     b       n2,a1   ;divide butterflies per group by two
  92.         lsl     a       b1,n0   ;multiply groups per pass by two
  93.         move            a1,n2
  94. _end_pass
  95. ;
  96. ; Do last FFT pass
  97. ;
  98.         move    n1,n0           ;correct pointer offset for last pass
  99.         move    #data,r0        ;initialize A input pointer
  100.         move    r0,r4           ;initialize A output pointer
  101.         lua     (r0)+,r1        ;initialize B input pointer
  102.         move    #coef,r6        ;initialize C input pointer
  103.         lua     (r1)-n1,r5      ;initialize B output pointer
  104.         move    x:(r1),x1       y:(r6),y0
  105.         move    x:(r5),a        y:(r0),b
  106.  
  107.         do      n2,_lastpass    ;Radix 2 DIT butterfly kernel with one
  108.         mac     x1,y0,b x:(r6)+n6,x0    y:(r1)+n1,y1    ;butterfly per group
  109.         macr    -x0,y1,b        a,x:(r5)+n5     y:(r0),a
  110.         subl    b,a     x:(r0),b        b,y:(r4)
  111.         mac     -x1,x0,b        x:(r0)+n0,a     a,y:(r5)
  112.         macr    -y1,y0,b        x:(r1),x1       y:(r6),y0
  113.         subl    b,a             b,x:(r4)+n4     y:(r0),b
  114. _lastpass
  115.         move    a,x:(r5)+n5
  116.         endm
  117.